替 SmartWonder 加上重新編號的功能

前一陣子在研究如何在 textarea 中刪除目前所在列的功能時，找到利用 document.selection 來取得目前選取的文字的方法，所以才想進一步完成這個重新編號的功能。

其實平時在打報告時倒不見得很常會需要重新編號，但需要的時候，第一點、第二點⋯⋯這樣一路打下來也是蠻花心力的，最常運用到的時機大概是跟賴主任打報告的時候吧，每次整理完 findings 要 copy & past 到 conclusions 時，總是得多做一個編號的動作，能省的時間當然要省囉，積少成多嘛！

功能示範

運作的方式大概是：

1. 算出目前選取的範圍行數
2. 擴充選取範圍至整行
3. 用 Regular Expression 的方式將內容替換掉

目前 code 放在 GitHub 未來應該還會做一些修改。

奇怪的 Hack

在 AutoHotKey 中 Array 的用法有點詭異，Array0 表示個數，Array[1…] 代表的各個項目，但利用像是 StringSplit¹ output 出來的 Array，似乎不會把 Array[1…] 這些項目清掉，導致重複執行這個 script 時，會用到錯誤的資料，因此在跑這個 function 前，都必須先手動把這些變數 reset。

可以加強的部分

因為目前 SmartWonder 系統只能限定在舊版 IE（或相容性模式）下運行，所以還可以用已經被 IE 10 後續版本廢棄的 document.selection，理論上如果要能在後續版本中使用，應該要同時併用 window.getSelection²，反正沒有急迫性，先暫時不動。^^a

單一檔案版本

因為許多 AutoHotKey Script 間都互有相依關係，如果只對這個功能有興趣的，可以使用下列版本，裡面包含會用到的相關函數

	; SmartWonder Extension
	; Renumbering Selected Lines
	; Group Control For SmartWonder
	GroupAdd, SmartWonder, VGHKS-
	GroupAdd, SmartWonder, vghks-
	GroupAdd, SmartWonder, tedpc-
	; WBGet()
	; Access an IE object by WinTitle and Internet Explorer_Server Number
	; By jethrow
	; http://www.autohotkey.com/board/topic/47052-basic-webpage-controls-with-javascript-com-tutorial/
	WBGet(WinTitle="ahk_class IEFrame", Svr#=1) { ;// based on ComObjQuery docs
	static msg := DllCall("RegisterWindowMessage", "str", "WM_HTML_GETOBJECT")
	, IID := "{0002DF05-0000-0000-C000-000000000046}" ;// IID_IWebBrowserApp
	;// , IID := "{332C4427-26CB-11D0-B483-00C04FD90119}" ;// IID_IHTMLWindow2
	SendMessage msg, 0, 0, Internet Explorer_Server%Svr#%, %WinTitle%
	if (ErrorLevel != "FAIL") {
	lResult:=ErrorLevel, VarSetCapacity(GUID,16,0)
	if DllCall("ole32\CLSIDFromString", "wstr","{332C4425-26CB-11D0-B483-00C04FD90119}", "ptr",&GUID) >= 0 {
	DllCall("oleacc\ObjectFromLresult", "ptr",lResult, "ptr",&GUID, "ptr",0, "ptr*",pdoc)
	return ComObj(9,ComObjQuery(pdoc,IID,IID),1), ObjRelease(pdoc)
	}
	}
	}
	#IfWinActive ahk_group SmartWonder
	$^!n::
	wb := WBGet()
	tabIframe2 := wb.document.frames["frameWork"].document.frames["tabIframe2"]
	ReportContent := tabIframe2.document.getElementsByName("ReportContent")[0]
	; get Caret
	;; ref: http://stackoverflow.com/a/3373056
	textRange := tabIframe2.document.selection.createRange()
	totalLen := StrLen(ReportContent.value)
	normalizedValue := ReportContent.value
	StringReplace, normalizedValue, normalizedValue, `r`n, `n, All
	textInputRange := ReportContent.createTextRange()
	textInputRange.moveToBookmark(textRange.getBookmark())
	endRange := ReportContent.createTextRange()
	endRange.collapse(false)
	if (textInputRange.compareEndPoints("StartToEnd", endRange) > -1) {
	startPos := endPos := totalLen
	} else {
	startPos := -textInputRange.moveStart("character", -totalLen)
	if (textInputRange.compareEndPoints("EndToEnd", endRange) > -1) {
	endPos := totalLen
	} else {
	endPos := -textInputRange.moveEnd("character", -totalLen)
	}
	}
	StringLeft, leftStr, normalizedValue, startPos
	StringSplit, strAry, leftStr, `n
	If (startPos) {
	startLine := strAry0
	startLineOffset := StrLen(strAry%startLine%)
	} Else { ; special condition, at the beginning: startPos == 0
	startLine := 1
	startLineOffset := 0
	}
	strAry1 := "" ; strange hack. traditional array do not GC ?
	StringLeft, leftStr, normalizedValue, endPos
	StringSplit, strAry, leftStr, `n
	StringSplit, norAry, normalizedValue, `n
	If (endPos) {
	endLine := strAry0
	} Else { ; special condition, at the beginning and no selection: endPos == 0
	endLine := 1
	}
	isEndNewLine := 0 ; strange hack. Variable do not GC ?
	If (StrLen(strAry%endLine%) = 0 && endLine > 1 && endLine > startLine) {
	isEndNewLine := 1
	endLine -= 1 ; 若最後一個字元是 \n 會多算一行
	}
	endLineOffset := StrLen(norAry%endLine%) - StrLen(strAry%endLine%)
	norLineText := norAry%endLine%
	norLineTextLen := StrLen(norAry%endLine%)
	endLineText := strAry%endLine%
	textRange.moveStart("character", -startLineOffset)
	textRange.moveEnd("character", endLineOffset)
	; numbering the selected text
	selectedText := textRange.text
	If (StrLen(selectedText) > 0) {
	finalText := ""
	currLineNo := 0
	Loop, Parse, normalizedValue, `n
	{
	If (A_Index >= startLine && A_Index <= endLine) {
	If (!RegExMatch(A_LoopField, "^\s*$")) {
	finalText .= ++currLineNo . ". " . RegExReplace(A_LoopField, "^(\s*)((\d+\.)|([-\+\*]))(\s*)(.*)", "$6")
	If (A_Index < endLine)
	finalText .= "`n"
	}
	Else {
	; if all line is empty, ignore it, and do not append an \n
	; finalText .= A_LoopField
	}
	}
	}
	If (isEndNewLine){
	finalText .= "`n"
	}
	textRange.text := finalText
	} Else {
	; No selection. Do nothing.
	}
	Return
	#IfWinActive

view raw SmartWonder-RenumberingSelectedLines.ahk hosted with by GitHub

Footnotes